Cream of the Crop 25/Cream of the Crop 25.iso/bbs/bradyref.zip/BRADY.REF

Text File | 1997-04-23 | 28KB | 1,509 lines

COMMENT A wild romp through the Brady house!

;vars it uses, but never saves

;`p01 - Does person have grape soda? (1 if yes)
;`p02 - carols location (1 if in kitchen)
;`p03 - how far did you go with Jan and Marsha?
;`p04 - Is Alice dead? (2 is yes)
;`p05 - Your score
;`p06 - Have you talked to Alice yet? (1 is yes)
;`p07 - 1 if has steak knife
;`p08 - 1 if has hand
;`p09 - 1 if has given hand to Carol
;`p10 - 1 if has searched the boys room
;`p11 - 1 if has joint
;`p12 - 1 if has talked to cindy

@#introansi
@version 79
;lets set all our vars to the defaults
@do `p01 is 0
@do `p02 is 0
@do `p03 is 0
@do `p04 is 0
@do `p05 is 0
@do `p06 is 0
@do `p07 is 0
@do `p08 is 0
@do `p09 is 0
@do `p10 is 0
@do `p11 is 0
@do `p12 is 0

@moremap
`r0  `7<`%MORE`7>
@progname
The Brady Bunch Adventure
@show
`2`%
                                  THE

                 ▀▀▀▀▀▀  ▀▀▀▀▀▀   ▀▀▀▀▀  ▀▀▀▀▀▀   ▀▀    ▀▀
                 ▀▀   ▀▀ ▀▀   ▀▀ ▀▀   ▀▀ ▀▀   ▀▀   ▀▀  ▀▀
                 ▀▀▀▀▀▀  ▀▀▀▀▀▀  ▀▀▀▀▀▀▀ ▀▀   ▀▀▀   ▀▀▀▀
                 ▀▀   ▀▀ ▀▀  ▀▀  ▀▀   ▀▀ ▀▀   ▀▀     ▀▀
                 ▀▀▀▀▀▀  ▀▀   ▀▀ ▀▀   ▀▀ ▀▀▀▀▀▀      ▀▀

                            BUNCH ADVENTURE

          `% Created by Seth A. Robinson for the LORD2 engine.

                  `7CONTAINS SOME MATURE SUBJECT MATTER.
@

@#START

@routine introansi
@label startloop
@show
`\                      `7(`%S`7)neak into the Brady house
                      `7(`%L`7)ist last ten players
                      `7(`%Q`7)uit back to the BBS
@do write
`\  `7What's it gonna be? (`%? for menu`7) [`%?`7] : `%
@do readspecial `s01 ?LSQ

@if `s01 is ? then goto start
@if `s01 is L then do
  @begin
  @do write
`c
  @routine rank
  @do goto start
  @end
@if `s01 is Q then do
  @begin
  @show
`\`\  `4Dohh! `7The Brady house will always be here when you change your mind!
  @closescript
  @end

 @if `s01 is S then do
   @begin
   @show
`c

             You carefully peek through a window - You don't see any
             Bradys in the living room, so you walk in.

`k
   @do goto lroom
   @end

@#mike
@do `p20 random 7 1
@if `p20 is 1 then do
  @begin
  @do `p20 random 7 1
  @if `p20 is 1 then do
   @begin
   @show
`\`7  You hear Mike Bradys voice not too far away...

`k
   @end

  @if `p20 is 2 then do
   @begin
   @show
`\`7  You hear Mike two rooms away from you.  Better hurry!

`k
   @end
  @if `p20 is 3 then do
   @begin
   @show
`\`7  You hear Mike, maybe from the stairs.

`k
   @end

  @if `p20 is 4 then do
   @begin
   @show
`\`7  `4Mike is in the room you are traveling to!

`k  `7Lukily, you see him in time.  You wait until he is gone before
  advancing.

`k
   @end

  @if `p20 is 5 then do
   @begin
   @show
`\`7  `4Mike is in the room you are traveling to!

`k  `4He sees you.

`k  `%"Young man, I don't know you - and frankly I think you're up to no
  good.  And a Brady always knows who his friends are." `7Mike tells you as
  he advances.

`k  `%"Why Mr. Brady!  I am here to see Greg.  I am a friend of his you
  don't know," `7you lie glibly.

`k  `7Mike mulls over your story.. he seems to be buying it!  `%"The boys
  aren't here today.. Why don't you go home and come back tomorrow?  I'm
  watching you..." `7he threatens as he leaves the room.

`k




   @end

  @if `p20 is 6 then do
   @begin
   @show
`\`7  `4Mike is in the room you are traveling to!

`k  `4He sees you.

`k  `%"You! Stop!  What are you doing in my house?"

  `7You smile.  `%"I know Marsha and Jan.  In the biblical sense, that is..."

`k  `7Mike looks pissed.  `%"My daughters are sleeping with you?!!  Those
  stupid sluts.  I'll deal with them later, as for you..."

`k  `bHE PULLS OUT A KNIFE AND SLASHES YOUR THROAT!

`k
  @routineabort
  @do goto finish
  @end

  @if `p20 is 7 then do
   @begin
   @show
`\`7  `4Mike is in the room you are traveling to!

`k  `4He sees you.

`k  `%"Who let you in?" `7he accuses.

`k  `%"Why, Mrs Brady did!"

  `7Mike doesn't look convinced.  `%"Prove it."

@if `p01 is 1 then do
  @begin
  @show
`k`7  You show Mike your `5Grape Soda`7.  He smiles warmly.  `%"Carol only
  gives those to friends.  And a friend of Carol's is a friend of mine."

  `7He walks away.

`k
  @end
@if `p01 is 0 then do
  @begin
  @show
  `7You have nothing to show him...He procedes to kick your ass.

`k
  @routineabort
  @do goto finish
  @end

   @end


  @end


@#help
@show
`c  `%Brady Bunch Adventure Help Screen

  `$This wacky funloving "Play it once" adventure was brought to you by
  RTsoft and Seth A. Robinson.  It is totally fictional and meant as a
  joke.  The author does not condone the use of drugs or murder in any
  way.

  `7? `%- `7Redraws the screen
  `7I `%- `7Inventory
  `7! `%- `7Score so far

  `7Your goal is to run around the house doing nasty things without being
  caught by `%Mike Brady`7, who is also roaming the house.

`k
@

@#inventory
@show
`c  `%Inventory`7

  You are holding:

@if `p01 is 1 then write
  `%- `7Can of `5grape`7 soda`\
@if `p07 is 1 then write
  `%- `7A steak knife`\
@if `p08 is 1 then write
  `%- `7Alice's hand`\
@if `p11 is 1 then write
  `%- `7A joint`\

@if `p01 is 0 then do
  @begin
   @if `p07 is 0 then do
    @begin
      @if `p08 is 0 then do
       @begin
        @if `p11 is 0 then do
         @begin
         @do write
  `%- `7Nothing.`\
         @end
      @end
    @end
  @end

@show
`\`k
@

@#score
@show
`c  `%Score`7

  Your score is `%`p05`7.

`k
@



@#lroom
@show
`c  `r1  `%LIVING ROOM `r0`\
@if `p02 is 1 then do
  @begin
 @show
  `7No one is here.  You hear noises from the kitchen.

  (`%K`7)itchen
  (`%U`7)pstairs
  (Q)uit back to the street
  @do write
`\  `7You are alone.  Now what? (`%H for help) : `%
  @do readspecial `s01 ?QKU!IH
  @do goto lroomread
  @end


  @end


@if `p01 is 0 then do
 @begin
 @show
  `%"Why hello there, young man!  Can I get you a soda?" cheerfully
  asks Carol, coming out of nowhere.

  Your heart nearly stops, but you quickly put down the vase.

  (A)sk for a drink
  (S)mart talk her
  `7(`%K`7)itchen
  (`%U`7)pstairs
  (Q)uit back to the street
  @do write
`\  `7Carol looks at you expectantly. (`%H for help`7) : `%
  @do readspecial `s01 ?QASKU!IH
  @end

@if `p01 is 1 then do
 @begin
 @show
  `%"Anything else I can do for you?" smiles Carrol.

  `7You can't help but stare at her tight little skirt.

  (S)mart talk her
  (`%K`7)itchen
  (`%U`7)pstairs
  (Q)uit back to the street
  @do write
`\  `7Carol looks at you expectantly. (`%H for help) : `%
  @do readspecial `s01 ?QASKU!IH
  @end

@label lroomread
@if `s01 is ? then goto lroom
@if `s01 is K then do
  @begin
  @routine mike
  @do goto kitchen
  @end
@if `s01 is H then do
  @begin
  @routine help
  @do goto lroom
  @end
@if `s01 is I then do
  @begin
  @routine inventory
  @do goto lroom
  @end
@if `s01 is ! then do
  @begin
  @routine score
  @do goto lroom
  @end


@if `s01 is Q then do
  @begin
  @show
`\  `7You hide behind the davenport until everybody leaves - then sneak
  on out.

`k
  @do goto finish
  @end

@if `s01 is S then do
  @begin
  @show
`\  `%"I'm here for your girls, Mrs. Brady,"`7 you smile.

  `%"Wonderful!  You must be the big man on campus, try upstairs," `7she offers.

  `7Carol saunters into the kitchen.

`k
  @do `p02 is 1 ;carol is in kitchen
  @do goto lroom
  @end
@if `s01 is A then do
  @begin
  @show
`\  `%"Mrs. Brady, I believe I would like a drink," `7you smile
  charmingly.

`k  `%"Wonderful!" `7she exclaims.  A minute later you have a grape soda
  in your hand.

`k
@do `p01 is 1 ;yeah, you have a soda
@do goto lroom
@end

@if `s01 is U then do
  @begin
  @show
`c  `7You carefully climb the stairs - noticing `4blood stains`7 on the second step.

`k
  @routine mike
  @do goto upstairs
  @end

@#upstairs
@show
`c  `r1`%  UPSTAIRS  `r0

`7  You see three doors.

  (`%G`7)irls room
  (`%B`7)oys room
  (`%L`7)aundry room
  (`%D`7)ownstairs
@
  @do write
`\  `7You are alone.  (`%H for help`7) : `%

@do readspecial `s01 ?GBLD!IH

@if `s01 is ? then goto upstairs
@if `s01 is H then do
  @begin
  @routine help
  @do goto upstairs
  @end
@if `s01 is I then do
  @begin
  @routine inventory
  @do goto upstairs
  @end
@if `s01 is ! then do
  @begin
  @routine score
  @do goto upstairs
  @end


@if `s01 is B then do
  @begin
  @routine mike
  @do goto boys
  @end

@if `s01 is G then do
  @begin
  @routine mike
  @do goto girls
  @end

@if `s01 is L then do
  @begin
  @routine mike
  @do goto laundry
  @end


@if `s01 is D then do
 @begin
 @routine mike
 @do goto lroom
 @end

@#girls
@show
`c  `r1`%  GIRLS ROOM  `r0

@if `p03 is 0 then do
 @begin
 @show
`7  Marhsa is sitting on her bed combing her hair.
  Jan is reading a book.

  (`%K`7)iss Marsha
  (`%B`7)athroom
  (`%G`7)o back to the hallway
  @do write
`\  `7Your command?  (`%H for help`7) : `%

@do readspecial `s01 ?KBG!IH
@end

@if `p03 is 1 then do
 @begin
 @show
`7  Marhsa is looking at you in amazement.
  Jan is reading a book.

  (`%K`7)iss Marsha Again
  (`%B`7)athroom
  (`%G`7)o back to the hallway
  @do write
`\  `7Your command?  (`%H for help`7) : `%

@do readspecial `s01 ?KBG!IH
@end

@if `p03 is 2 then do
 @begin
 @show
`7  Marsha is smiling smugly at Jan.
  Jan is sulking.

  (`%A`7)sk Jan to join Marsha for a threesome
  (`%B`7)athroom
  (`%G`7)o back to the hallway
  @do write
`\  `7Your command?  (`%H for help`7) : `%

@do readspecial `s01 ?ABG!IH
@end

@if `p03 is 3 then do
 @begin
 @show
`7  Jan and Marsha are laying on the bed, still sweaty from your little
  'get together'.

  (`%A`7)sk Jan to join Marsha for a threesome
  (`%B`7)athroom
  (`%G`7)o back to the hallway
  @do write
`\  `7Your command?  (`%H for help`7) : `%

@do readspecial `s01 ?ABG!IH
@end

@if `s01 is ? then goto girls



@if `s01 is H then do
  @begin
  @routine help
  @do goto girls
  @end
@if `s01 is I then do
  @begin
  @routine inventory
  @do goto girls
  @end
@if `s01 is ! then do
  @begin
  @routine score
  @do goto girls
  @end

@if `s01 is B then do
  @begin
  @routine mike
  @do goto bath
  @end

@if `s01 is G then do
 @begin
 @routine mike
 @do goto upstairs
 @end
@if `s01 is K then do
  @begin
   @if `p03 is 0 then do
    @begin
    @show
`\  `7You grab Marsha and make out with her.  She looks shocked.

`k
   @do `p03 is 1
   @do goto girls
   @end

   @if `p03 is 1 then do
    @begin
    @show
`\  `7You sit down on the bed and take your time with Marsha.

  Jan puts down her book and looks at you.  `#"Why does everyone
  choose Marsha?!"

`k
   @do `p03 is 2
   @do goto girls
   @end

  @end

@if `s01 is A then do
  @begin
  @if `p04 is 0 then do
   @begin
   @show
`\  `%"Um, Jan?  How 'bout you join your sister and and we all have a REALLY
  fun time?" `7you ask hopefully.

  Jan shakes her head.  `#"How gross! But... I've always secretly
  hated `%Alice`#.. If you can get rid of her I'll do it!"

`k
   @do `p04 is 1
   @do goto girls
   @end
  @if `p04 is 1 then do
   @begin
   @show
`\`7  `#"I told you! Get rid of Alice!!" `7she whines.

`k
   @do goto girls
   @end

  @if `p04 is 3 then do
   @begin
   @show
`\  `%"Hey girls, how 'bout some more fun!?" `7you ask.

  `#"But we're too tired!" `7they wail in unisen.
`\`k
   @do goto girls
   @end

  @if `p04 is 2 then do
   @begin
   @show
`\  `%"She is dead Jan, now put out or get out," `7you inform.

  Jan agrees and goes into the bathroom and change.

`k`c  `7Jan comes out wearing a black lace teddy!

`k  `#"It's the new Jan Brady!" `7she screams as she jumps on you and
  Marsha.

  `%YOU GET 10 POINTS!
`\`k
   @do `p05 + 10 ;give 'em some points
   @do `p03 is 3
   @do `p04 is 3

   @do goto girls
   @end


  @end


@#laundry
@show
`c  `r1`%  LAUNDRY ROOM  `r0

@if `p03 is 3 then do
  @begin
   @if `p07 is 1 then do
   @begin
   @if `p08 is 0 then do
    @begin
    @show
`7  You are alone.  The dryer has stopped and you can make out the
  limp form of Alice inside of it with one hand hanging out.

  (`%K`7)nife Alice
  (`%G`7)o back to hallway
  @do write
`\  `7Your command?  (`%H for help`7) : `%

  @do readspecial `s01 ?GK!IH
  @do goto launstart
  @end
  @end
  @show
`7  You are alone.  The dryer has stopped and you can make out the
  limp form of Alice inside of it with one hand hanging out.

  (`%G`7)o back to hallway
  @do write
`\  `7Your command?  (`%H for help`7) : `%

  @do readspecial `s01 ?G!IH
  @do goto launstart
  @end

@if `p04 is 2 then do
  @begin
  @show
`7  You are alone.  The see a pair of legs sticking out of the
  dryer going 'round and 'round.

  (`%G`7)o back to hallway
  @do write
`\  `7Your command?  (`%H for help`7) : `%

  @do readspecial `s01 ?G!IH
  @do goto launstart
  @end



 @if `p04 is 0 then do

@begin
  @show
`7  Alice is here stuffing clothes into the dryer.

  (`%C`7)hat with Alice
  (`%G`7)o back to hallway
  @do write
`\  `7Your command?  (`%H for help`7) : `%

  @do readspecial `s01 ?CG!IH
  @end
  @if `p04 is 1 then do
  @begin
  @show
`7  Alice is here stuffing clothes into the dryer.

  (`%C`7)hat with Alice
  (`%K`7)ill Alice
  (`%G`7)o back to hallway
  @do write
`\  `7Your command?  (`%H for help`7) : `%

  @do readspecial `s01 ?KCG!IH
  @end


@end

@label launstart
@if `s01 is ? then goto laundry
@if `s01 is H then do
  @begin
  @routine help
  @do goto laundry
  @end
@if `s01 is I then do
  @begin
  @routine inventory
  @do goto laundry
  @end
@if `s01 is ! then do
  @begin
  @routine score
  @do goto laundry
  @end

@if `s01 is G then do
  @begin
  @routine mike
  @do goto upstairs
  @end
@if `s01 is K then do
  @begin
  @if `p04 is 3 then do
   @begin
  @show
`\  `7Alice's arm flops around crazily as you saw it.  Blood begins to
  spurt as you cut through an artery.

`k  `%YOU HAVE ALICE'S HAND.
`\`k
  @do `p08 is 1
   @do goto laundry
   @end
  @end

@if `s01 is C then do
  @begin
  @if `p06 is 0 then do
   @begin
   @show
`\  `%"Hi, Alice.  You have a nice ass, you know that?" `7you complement.

  `#"Thanks Pal! I wish Sam would say that sometime!" `7she laughs.
`\`k
   @do `p06 is 1
   @do goto laundry
   @end
  @if `p06 is 1 then do
   @begin
   @show
`\  `#"I'd love to chat, I gotta do this laundry for Mrs. Brady!"
`\`k
  @do goto laundry
   @end
  @end

  @if `s01 is K then do
   @begin
   @show
`\  `7You savagly grab Alice and stuff her in the dryer.  You set the
  timer for a full hour.
`\`k
   @do `p04 is 2
   @do goto laundry
   @end

@#kitchen
@show
`c  `r1`%  KITCHEN  `r0

 @if `p09 is 2 then do
  @begin
  @show
`7  Carol is laying on the table naked and tired.

  (`%G`7)arage
  (`%L`7)iving room
  @do write
`\  `7Your command?  (`%H for help`7) : `%

  @do readspecial `s01 ?GL!IH
  @do goto kstart
  @end



 @if `p02 is 1 then do
  @begin
 @if `p08 is 1 then do
  @begin
  @show
`7  Carol is kneading the loaf - it is turning you on.
`\  (`%S`7)educe Carol
  (`%O`7)ffer a hand
  (`%G`7)arage
  (`%L`7)iving room
  @do write
`\  `7Your command?  (`%H for help`7) : `%

  @do readspecial `s01 ?SOGL!IH
  @do goto kstart
  @end



   @if `p07 is 0 then do
    @begin
    @show
`7  Carol is here making meatloaf with a kitchen knife.
    @end

   @if `p07 is 1 then do
    @begin
    @show
`7  Carol is here making meatloaf with her hands.
    @end

    @show
`\  (`%S`7)educe Carol
  (`%G`7)arage
  (`%L`7)iving room
  @do write
`\  `7Your command?  (`%H for help`7) : `%

  @do readspecial `s01 ?SGL!IH
  @end

 @if `p02 is 0 then do
  @begin
  @if `p07 is 0 then do
   @begin
   @show
`7  The room is empty.  You see something on the counter.

  (`%P`7)ickup steak knife
  (`%G`7)arage
  (`%L`7)iving room
  @do write
`\  `7Now what, master?  (`%H for help`7) : `%

   @do readspecial `s01 ?PGL!IH
   @end
  @if `p07 is 1 then do
   @begin
   @show
`7  The room is empty.

  (`%G`7)arage
  (`%L`7)iving room
  @do write
`\  `7Now what, Master?  (`%H for help`7) : `%
   @do readspecial `s01 ?GL!IH
   @end
  @end

 @label kstart
 @if `s01 is ? then do
  @begin
  @routine mike
  @do goto kitchen
  @end
 @if `s01 is L then do
  @begin
  @routine mike
  @do goto lroom
  @end
 @if `s01 is H then do
  @begin
  @routine help
  @do goto kitchen
  @end
 @if `s01 is I then do
  @begin
  @routine inventory
  @do goto kitchen
  @end
 @if `s01 is ! then do
  @begin
  @routine score
  @do goto kitchen
  @end

 @if `s01 is P then do
  @begin
  @show
`\  `7You take the knife.
`\`k
  @do `p07 is 1
  @do goto kitchen
  @end

  @if `s01 is S then do
   @begin
   @if `p09 is 1 then do
    @begin
     @show
`\`7  `%"You know Carol... I don't see Mike anywhere.  You must get lonely."

  `7Carol looks noticably disturbed.  `#"What are you saying?"

`k  `%"Only this; I am here right now.  Before he comes home from work why
  don't we enjoy ourselves a little bit?"

`k  `#"Take me, &realname!" `7Carol screams as she rips her blouse.

`k  `7Ten minutes later... `%YOU GET 5 POINTS.

`k
    @do `p05 + 5
    @do `p09 is 2
    @do goto kitchen
    @end

   @show
`\  `%"Hey baby, need some extra meat for your loaf?" `7 you wink.

`k  `#"No thanks young man! I'm sure Alice has plenty for me."
`\  `7This gives you a REALLY evil idea.
`\`k
   @do goto kitchen
   @end
   @if `s01 is O then do
  @begin
  @show
`\  `%"Why Carrol - how 'bout some extra spice with this," `7you snicker as you
  you slap Alice's hand on the table.

`k  `#"What a wonderful idea, young man.  Oh that Alice!" `7smiles Carol in
  mock exasperation.

`k
  @do `p08 is 0
  @do `p09 is 1
  @do goto kitchen
  @end

@if `s01 is G then do
  @begin
  @routine mike
  @do goto garage
  @end

@#GARAGE

@show
`c  `r1`%  GARAGE  `r0

`7  You feel like retching when you are confronted with the ugliest
  station wagon you have ever beheld.

  (`%K`7)itchen
  (`%B`7)ack Yard
@
  @do write
`\  `7You are alone.  (`%H for help`7) : `%

@do readspecial `s01 ?KB!IH

@if `s01 is ? then goto garage
@if `s01 is H then do
  @begin
  @routine help
  @do goto garage
  @end
@if `s01 is I then do
  @begin
  @routine inventory
  @do goto garage
  @end
@if `s01 is ! then do
  @begin
  @routine score
  @do goto garage
  @end


@if `s01 is B then do
  @begin
  @routine mike
  @do goto backyard
  @end

@if `s01 is K then do
  @begin
  @routine mike
  @do goto kitchen
  @end


@#BOYS

@show
`c  `r1`%  BOYS ROOM `r0

@if `p05 > 19 then do
  @begin
  @show
`7  Looks like the boys are out.  Good.

  (`%L`7)ook under Peters bed
  (`%G`7)o back to the hall
@
  @do write
`\  `7You are alone.  (`%H for help`7) : `%

@do readspecial `s01 ?LG!IH
  @do goto startboys
  @end
@show
`7  Looks like the boys are out.  Good.

  (`%S`7)each through the drawers
  (`%G`7)o back to the hall
@
  @do write
`\  `7You are alone.  (`%H for help`7) : `%

@do readspecial `s01 ?SG!IH
@label startboys
@if `s01 is ? then goto boys
@if `s01 is H then do
  @begin
  @routine help
  @do goto boys
  @end
@if `s01 is I then do
  @begin
  @routine inventory
  @do goto boys
  @end
@if `s01 is ! then do
  @begin
  @routine score
  @do goto boys
  @end


@if `s01 is L then do
  @begin
  @if `p11 is 1 then do
   @begin
   @show
`\  `7You better get rid of the joint you have, first.

`k
   @do goto boys
   @end
  @show
`\  `7You look under Peters bed.  Under some dirty magazines you find
  another joint!  This is too easy.

`k
  @do `p11 is 1
  @do goto boys
  @end

@if `s01 is G then do
  @begin
  @show
`\  `7You carefully shut the door on your way out.. they will never know you
  were here.. The fools!  Moohahaha!

`k
  @routine mike
  @do goto upstairs
  @end

@if `s01 is S then do
  @begin
  @show
`\  `7You frantically begin opening and closing drawers and spilling the
  contents on the ground.

  @if `p10 is 0 then do
  @begin
  @show
  You find.`l.`l.`l.`%A JOINT!
`\  `7Who would have thought little Bobby would have had this?!

`k
  @do `p10 is 1
  @do `p11 is 1
  @do goto boys
  @end

  @show
  You find.`l.`l.`l.`%`4Nothing`7.

  Looks like you cleaned 'em out.

`k
  @do goto boys
  @end



@#BACKYARD

@if `p12 is 2 then do
  @begin
  @if `p11 is 1 then do
    @begin
@show
`c  `r1`%  BACKYARD `r0

`7  Cindy is all giggles as she staggers around the yard.

  (`%S`7)moke more with Cindy
  (`%G`7)arage
@
  @do write
`\  `7Now what?  (`%H for help`7) : `%

@do readspecial `s01 ?SG!IH
  @do goto backstart
  @end

@show
`c  `r1`%  BACKYARD `r0

`7  Cindy is all giggles as she staggers around the yard.

  (`%G`7)arage
@
  @do write
`\  `7Now what?  (`%H for help`7) : `%

@do readspecial `s01 ?G!IH
  @do goto backstart
  @end


@if `p12 is 1 then do
  @begin

  @if `p11 is 1 then do
   @begin
@show
`c  `r1`%  BACKYARD `r0

`7  Cindy is sitting on a swing crying.

  (`%C`7)heer her up some more
  (`%O`7)ffer her a smoke
  (`%G`7)arage
@
  @do write
`\  `7You feel sorry for her.  (`%H for help`7) : `%

@do readspecial `s01 ?OCG!IH

   @do goto backstart
   @end

@show
`c  `r1`%  BACKYARD `r0

`7  Cindy is sitting on a swing crying.

  (`%C`7)heer her up some more
  (`%G`7)arage
@
  @do write
`\  `7You feel sorry for her.  (`%H for help`7) : `%

@do readspecial `s01 ?CG!IH


  @do goto backstart
  @end



@show
`c  `r1`%  BACKYARD `r0

`7  Cindy is here kicking a ball around.  She looks kinda bummed out.

  (`%A`7)ttempt to cheer her up
  (`%G`7)arage
@
  @do write
`\  `7Now what?  (`%H for help`7) : `%

@do readspecial `s01 ?AG!IH

@label backstart
@if `s01 is ? then goto backyard
@if `s01 is H then do
  @begin
  @routine help
  @do goto backyard
  @end
@if `s01 is I then do
  @begin
  @routine inventory
  @do goto backyard
  @end
@if `s01 is ! then do
  @begin
  @routine score
  @do goto backyard
  @end

@if `s01 is G then do
  @begin
  @routine mike
  @do goto garage
  @end

@if `s01 is S then do
  @begin
  @show
`\  `7Cindy gets even more wasted after you smoke another joint with her!

`k  `%YOU GET ONE POINT.

`k
  @do `p11 is 0
  @do `p05 + 1
  @do goto backyard
  @end

@if `s01 is C then do
  @begin
  @show
`\  `%"Cindy.. Cindy?  Don't feel bad, it's all gonna be ok,"`7 you console.

  `7Her tear stained face looks up with a glimmer of hope. `#"Really?"

`k  `%"No.. but it would have been `7- `%if you parents had only gotten that
  `4ABORTION`% they wanted to so you wouldn't be here now!" `7you accuse
  cruelly.

`k  `7Despite your attempts to console her she is still crying.  You need
  a new plan.

`k
  @do goto backyard
  @end

@if `s01 is O then do
  @begin
  @show
`\  `7You light up and take a few puffs.  Cindy looks interested.

  `#"What's that mithter?"

`k  `%"Nuthin.. why you want some?"

  `7She shaked her head. `#"I'm too little to thmoke."

`k  `%"Bobby's doing it.. I guess he was right, girls are chicken." `7you
  sigh as you delicately set the trap.

`k  `%CINDY GRABS THE JOINT FROM YOUR HAND AND STARTS SMOKING IT!

`7  10 minutes later she is feeling lots better.

  `%YOU GET 5 POINTS.

`k
  @do `p11 is 0
  @do `p12 is 2
  @do `p05 + 5
  @do goto backyard
  @end

@if `s01 is A then do
  @begin
  @show
`\  `7You signal Cindy to come over and talk.  `%"Cindy, what's wrong?  Why
  so down today?"

`k  `#"My daddy hith my mommie thomtimes," `7she tells you somberly.

  `7You are shocked - they looked like the perfect family!!

`k  `#"Daddy drinkth a lot too.  I don't think he loveth me." `7she cries.

  (`%M`7)ake her feel like it is her fault
  (`%A`7)ct like it's normal and she needs to get with the program

  @do write
  `7Cindy searches your face for an answer. [`%M`7] :
  @do readspecial `s01 MA
  @if `s01 is M then do
   @begin
   @show
`\  `%"Cindy..  The reason your dad is doing this is because you have not
  been a good daughter.  Your mom is getting hit because you didn't clean
  your room last week.  Is this what you want?  Well I hope you're happy!"

  `7Cindy burst into tears.  You turn away so she won't see you trying to
  stiffle a giggle.

`k
  @do `p12 is 1 ;talked to Cindy
  @do goto backyard
  @end
  @show
`\  `%"Dear niave Cindy.  Don't you know all families are like this?  Later,
  your husband will hit you too.  All husbands do it.  You women need to be
  trained, ya know?" `7you tell her matter of factly.

  `#"But I thought.. I thought," `7stammers Cindy.

`k  `%"You thought what?!  Oh grow up!  Men drink just so they can put up
  with tiny brained animals like you.  At least your sisters have looks,
  but you have nothing," `7you finish - operation `5"emotionally damage Cindy"`7
  is a success!  She is crying now.

`k
  @do `p12 is 1 ;talked to Cindy
  @do goto backyard
  @end

  @end

@#BATH

@show
`c  `r1`%  BATHROOM `r0

@if brady.txt exist true then do
  @begin
  @show
  `7You see written on the glass:

  @displayfile brady.txt
  @show

  @end

@show
`7  You see lipstick on the counter.

  (`%U`7)se lipstick to write on the glass
  (`%G`7)o back to the girls room
@
  @do write
`\  `7You are alone.  (`%H for help`7) : `%

@do readspecial `s01 ?UG!IH

@if `s01 is ? then goto bath
@if `s01 is H then do
  @begin
  @routine help
  @do goto bath
  @end
@if `s01 is I then do
  @begin
  @routine inventory
  @do goto bath
  @end
@if `s01 is ! then do
  @begin
  @routine score
  @do goto bath
  @end


@if `s01 is G then do
  @begin
  @routine mike
  @do goto girls
  @end

@if `s01 is U then do
  @begin
  @do goto glasswrite
  @show
`\  `7You write on the glass.

`k
  @do goto bath
  @end

@#glasswrite
@do delete brady.txt
@show

  `%Enter your message, blank line to quit.

@label writeagain
@do write
`x`x`7
@do readstring 76 NIL `s01 <--Read string, NIL is default. (nothing)
@do `p20 is length `s01
@if `p20 less 3 then do
  @begin
  @do goto bath
  @end
@show

@writefile brady.txt
  `$`s01
@do goto writeagain

@#finish

@do `s01 is Alice
@do `p25 is 0
@if brady.hi exist true then do
  @begin
  @readfile brady.hi
`s01
`p25
 @end


@if `p05 > `p25 then do
  @begin
  @show
                  `b** `%YOU ARE THE NEW GRAND CHAMPION!! YEAH! `b**`%

  @if brady.hi exist true then delete brady.hi
  @writefile brady.hi
&realname
`p05
  @do `s01 is &realname
  @do `p25 is `p05
 @end

@do `s02 is &realname
@do pad `s02 27
@do `s03 is `p05
@do pad `s03 5

@writefile brady.dat
            `7`s02     `% `s03 `7  &quickdate
@do trim brady.dat 10


@routine rank

@halt

@#rank
@do `s01 is Alice
@do `p25 is 0
@if brady.hi exist true then do
  @begin
  @readfile brady.hi
`s01
`p25
 @end


@show
                 `#Grand Champion is `%`s01`# with a score of `%`p25`#!

@show
                     `$Last Ten People To Visit The Bradys

            `%Name                          Score      Time played
          `8 ──────────────────────────────────────────────────────────
@if brady.dat exist true then do
  @begin
  @displayfile brady.dat
  @end
@if brady.dat exist false then do
  @begin
  @show
             `7Whups.  Nobody has had the balls to sneak in yet.
  @end


@show

`k


@#done